home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / MISC / HCAL-27 / WIREMESH.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1997-01-29  |  4.1 KB  |  139 lines
  1. 10  'WIREMESH - Wire Mesh Screening - 24 FEB 96 rev. 28 SEP 96
  2. 20  IF EX$=""THEN EX$="EXIT"
  3. 30  CLS:KEY OFF
  4. 40  COLOR 7,0,1
  5. 50  U$="#####.###"
  6. 60  U1$="#####.#"
  7. 70  UL$=STRING$(80,205)
  8. 80  PI=3.14159
  9. 90  DIM WP(11)
  10. 100  DATA .3, .8, 1.3, 2.1, 3.1, 4.2, 5.5, 6.9, 8.5, 10.3, 12.3
  11. 110  FOR Z=1 TO 11:READ WP(Z):NEXT Z
  12. 120  GOTO 200
  13. 130  '
  14. 140  '.....format input line
  15. 150  LOCATE CSRLIN-1:PRINT SPC(7);
  16. 160  IF ZZ=SA THEN X$=U1$ ELSE X$=U$
  17. 170  LOCATE CSRLIN,47:PRINT STRING$(7,".");USING X$;ZZ;
  18. 180  RETURN
  19. 190  '
  20. 200  '.....start
  21. 210  CLS
  22. 220  COLOR 15,2
  23. 230  PRINT " WIRE MESH SCREENING";TAB(57)"by George Murphy VE3ERP ";
  24. 240  COLOR 1,0:PRINT STRING$(80,223);
  25. 250  COLOR 7,0
  26. 260  GOSUB 940   'preface
  27. 270  PRINT UL$;
  28. 280  COLOR 0,7
  29. 290  LOCATE,22:PRINT " Press 1 to continue or 0 to quit...."
  30. 300  COLOR 7,0
  31. 310  Z$=INKEY$:IF Z$=""THEN 310
  32. 320  IF Z$="0"THEN CLS:RUN EX$
  33. 330  IF Z$="1"THEN 430
  34. 340  GOTO 310
  35. 350  '
  36. 360  '.....mesh cell data (LS=lgth.of side, CA=cell area, WL=wire length
  37. 370  '.....(calculation for hex mesh - results same for square mesh)
  38. 380  LS=1.155*A/2:CA=3.464*(A/2)^2:WL=3*LS
  39. 390  LSO=1.155*(A-D)/2:OA=3.464*((A-D)/2)^2           'open area
  40. 400  WA=CA-OA:GOTO 410                                'wire area
  41. 410  RETURN
  42. 420  '
  43. 430  '.....inputs
  44. 440  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  45. 450  PRINT " SQUARE OR HEXAGONAL WIRE MESH SCREEN"
  46. 460  INPUT " ENTER: c.c. Distance across mesh opening.......(in.)";A
  47. 470  ZZ=A:GOSUB 140:PRINT " in.";TAB(68)USING U1$;A*25.4;:PRINT " mm"
  48. 480  INPUT " ENTER: Wire diameter...........................(in.)";D
  49. 490  ZZ=D:GOSUB 140:PRINT " in.";TAB(68)USING U1$;D*25.4;:PRINT " mm"
  50. 500  COLOR 0,7
  51. 510  INPUT " ENTER: Screen area.............................(ft<UNK! {FD29}>";SA
  52. 520  ZZ=SA:GOSUB 140:PRINT " ft<UNK! {FD22}>;TAB(68)USING U1$;SA*0.0929;:PRINT " m<UNK! {FD20}>  ";
  53. 530  COLOR 7,0
  54. 540  '
  55. 550  GOSUB 360         'cell data
  56. 560  WV=WL*PI*(D/2)^2  'wire volume per cell
  57. 570  N=SA/CA*144       'total number of cells
  58. 580  TV=WV*N           'total wire volume
  59. 590  FF=WA/CA          'filled area factor
  60. 600  FA=SA*FF          'wind vane area
  61. 610  WTA=0.0975         'weight/cu.in. of aluminum
  62. 620  WTC=0.321          'weight/cu.in. of copper
  63. 630  WTS=0.2835         'weight/cu.in. of steel
  64. 640  Z=TV*WTA
  65. 650  PRINT "        Weight of this area of mesh: aluminum wire...";
  66. 660  PRINT USING U1$;Z;:PRINT " lb.";TAB(68)USING U1$;Z*0.4536;:PRINT " kg"
  67. 670  Z=TV*WTS
  68. 680  PRINT "                                     steel wire......";
  69. 690  PRINT USING U1$;Z;:PRINT " lb.";TAB(68)USING U1$;Z*0.4536;:PRINT " kg"
  70. 700  Z=TV*WTC
  71. 710  PRINT "                                     copper wire.....";
  72. 720  PRINT USING U1$;Z;:PRINT " lb.";TAB(68)USING U1$;Z*0.4536;:PRINT " kg"
  73. 730  PRINT "        Percent of screen area filled by wire........";
  74. 740  PRINT USING U1$;FF*100;:PRINT " %"
  75. 750  PRINT "        Wind vane area (screen area filled by wire)..";USING U1$;FA;
  76. 760  PRINT " ft<UNK! {FD22}>;TAB(68)USING U1$;FA*0.0929;:PRINT " m<UNK! {FD22}>
  77. 770  PRINT "        Wind load on this area of vertical mesh at various ";
  78. 780  PRINT "wind speeds:"
  79. 790  '
  80. 800  X=0
  81. 810  FOR Z=1 TO 6 STEP 0.5
  82. 820  SM=Z*10*1.1508
  83. 830  KM=Z*10*1.8519
  84. 840  X=X+1
  85. 850  Y=WP(X)*FA
  86. 860  PRINT "          @ ";USING "##";Z*10;
  87. 870  PRINT " knots =";USING "###";SM;:PRINT " mph =";USING "###";KM;
  88. 880  PRINT " km/hr ............";
  89. 890  PRINT USING U1$;Y;:PRINT " lb.";TAB(68)USING U1$;Y*0.4536;:PRINT " kg"
  90. 900  NEXT Z
  91. 910  GOTO 1220
  92. 920  END
  93. 930  '
  94. 940  '.....preface
  95. 950  T=(7)
  96. 960  PRINT TAB(T);
  97. 970  PRINT "This program may be used in the design of reflectors for antennas"
  98. 980  PRINT TAB(T);
  99. 990  PRINT "in the VHF/UHF frequency range, or for anything else you want to"
  100. 1000  PRINT TAB(T);
  101. 1010  PRINT "make out of chain link fencing, chicken wire, hardware cloth, or"
  102. 1020  PRINT TAB(T);
  103. 1030  PRINT "window screening.
  104. 1040  PRINT
  105. 1050  PRINT TAB(T);
  106. 1060  PRINT "The calculated effects of wind do not apply if any part of the mesh"
  107. 1070  PRINT TAB(T);
  108. 1080  PRINT "is covered by ice, snow, leaves, plastic sheets, or other matter"
  109. 1090  PRINT TAB(T);
  110. 1100  PRINT "that obstructs the free passage of air through the mesh."
  111. 1110  PRINT
  112. 1120  PRINT TAB(T);
  113. 1130  PRINT "A hexagonal mesh screen of a given size contains the same amount of"
  114. 1140  PRINT TAB(T);
  115. 1150  PRINT "wire as a square mesh screen of the same size, if both screens have"
  116. 1160  PRINT TAB(T);
  117. 1170  PRINT "the same size mesh (i.e. same distance between between opposite"
  118. 1180  PRINT TAB(T);
  119. 1190  PRINT "sides of the hexagonal or square opening)."
  120. 1200  RETURN
  121. 1210  '
  122. 1220  '.....end
  123. 1230  GOSUB 1260:GOTO 200
  124. 1240  END
  125. 1250  '
  126. 1260  'HARDCOPY
  127. 1270  GOSUB 1380:LOCATE 25,2:COLOR 14,6
  128. 1280  PRINT " Press 1 to print screen, 2 to print screen & ";
  129. 1290  PRINT "advance paper, or 3 to continue.";:COLOR 7,0
  130. 1300  Z$=INKEY$:IF Z$="3"THEN GOSUB 1380:RETURN
  131. 1310  IF Z$="1"OR Z$="2"THEN GOSUB 1380:GOTO 1330
  132. 1320  GOTO 1300
  133. 1330  FOR QX=1 TO 24:FOR QY=1 TO 80
  134. 1340  LPRINT CHR$(SCREEN(QX,QY));
  135. 1350  NEXT QY:NEXT QX
  136. 1360  IF Z$="2"THEN LPRINT CHR$(12)
  137. 1370  GOTO 1270
  138. 1380  LOCATE 25,1:PRINT STRING$(80,32);:RETURN
  139.